Mikrotik yordamida ixtiyoriy saytlarni bloklash.

Youtube va Instagram saytlarini bloklash keltrilgan. Boshqa saytlarni shu na’muna asosida bloklasa bo’ladi.

1. DNS So‘rovlarini Ushtlab Olish

Avvalo, routeringiz barcha DNS so‘rovlarini ushlab olish uchun quyidagi NAT qoidalarini qo‘shing:

/ip firewall nat
add action=redirect chain=dstnat comment="DNS TCP" dst-port=53 protocol=tcp to-ports=53
add action=redirect chain=dstnat comment="DNS UDP" dst-port=53 protocol=udp to-ports=53

Keyin, “restricted” address-listdagi IP manzillarga kirishni bloklash uchun quyidagi firewall qoidasini yarating:

/ip firewall filter
add chain=forward dst-address-list=restricted action=drop

2. Saytlarni Bloklash Skripti

Quyidagi skript DNS keshi yozuvlarini tekshiradi. Agar yozuv nomida “instagram” yoki “youtube” so‘zlari aniqlansa, u holda tegishli IP manzil “restricted” address-listga qo‘shiladi. Ushbu skriptni tizimga avtomatik ishga tushirish uchun jadvalga qo‘yishingiz mumkin (masalan, har 30 soniyada).

:foreach i in=[/ip dns cache find] do={
    :local bNew "true";
    :local cacheName [/ip dns cache all get $i name];
    # :put $cacheName;
    :if (([:find $cacheName "instagram"] >= 0) || ([:find $cacheName "youtube"] >= 0)) do={
        :local tmpAddress [/ip dns cache get $i address];
        # :put $tmpAddress;
        # Agar address-list bo‘sh bo‘lsa, tekshirishni o'tkazib yuboramiz
        :if ([/ip firewall address-list find list="restricted"] = "") do={
            :log info ("added entry: $[/ip dns cache get $i name] IP $tmpAddress");
            /ip firewall address-list add address=$tmpAddress list=restricted comment=$cacheName;
        } else={
            :foreach j in=[/ip firewall address-list find list="restricted"] do={
                :if ([/ip firewall address-list get $j address] = $tmpAddress) do={
                    :set bNew "false";
                }
            }
            :if ($bNew = "true") do={
                :log info ("added entry: $[/ip dns cache get $i name] IP $tmpAddress");
                /ip firewall address-list add address=$tmpAddress list=restricted comment=$cacheName;
            }
        }
    }
}

3. Qo‘shimcha Izohlar

• Skript ishlash tamoyili:
  Skript DNS keshi yozuvlarini tekshiradi va nomida “instagram” yoki “youtube” bo‘lgan saytlarning IP manzillarini aniqlaydi. Aniqlangan IP manzillar “restricted” address-listga qo‘shiladi va shu tarzda firewall qoidasi yordamida ushbu IP manzillarga kirish bloklanadi.
• Moslashtirish:
  Agar siz boshqa saytlarni ham bloklamoqchi bo‘lsangiz, skript ichidagi [:find $cacheName "instagram"] va [:find $cacheName "youtube"] qismlariga kerakli sayt nomlarini qo‘shishingiz mumkin.
• Jadvalga qo‘yish:
  Skriptni avtomatik ishga tushirish uchun Scheduler modulidan foydalaning. Masalan, har 30 soniyada bir marta ishga tushishi uchun yangi vazifa yarating.

Xulosa

Ushbu metod yordamida siz Mikrotik RouterOS tizimida web proxy’dan foydalanmasdan, DNS keshi orqali “Instagram” va “YouTube” saytlariga kirishni bloklashingiz mumkin. Bu usul tarmog’ingizni istalmagan trafikdan himoya qilishda samarali yechim bo‘lib xizmat qiladi. Agar qo‘shimcha savollar bo‘lsa yoki boshqa saytlarni ham bloklash usullari haqida bilmoqchi bo‘lsangiz, izohlarda yozib qoldiring.

Omad tilaymiz!